'' RED MpegBatcher script
 '' Convert all .AVI files without an .MPG counterpart to .MPG using TPMegEnc
 ''
 '' By Sander Steenhuis
 '' 2008-09-07
 '' http://www.REDnet.nl/en/
 
 ' Usage:
 '
 ' Copy this script to a folder full of .AVI's.
 ' Copy a random video file to P:\Temp\TMPGEncBatcher.avi (with same specs as the files you are going to convert)
 ' Open TMPGEnc, load P:\Temp\TMPGEncBatcher.avi, apply your favorite settings, press ctrl+alt+M (Add project to Batch List), use P:\Temp\TMPGEncBatcher.avi as name, exit TMPGEnc.
 '
 ' Notes:
 '
 ' Above filenames, drives and folders should correspondent to the ones used in this script.
 ' You can change them somewhere below, but use your brain.
 
 Option Explicit
 'On Error Resume Next
 Dim fso: Set fso = CreateObject("Scripting.FileSystemObject")
 Dim currentFolder, fileDone, fileSkip, fsoDo, fileMpeg
 
 
 
 ' Set this to your TMPGEnc path INCLUDING END SLASH.
 Dim TMPGEncPath: TMPGEncPath = "D:\Software\Video\TMPGEnc Free\"
 ' Set this to your TMPGEnc executable.
 Dim TMPGEnc: TMPGEnc = "TMPGEnc.exe"
 ' Set this to your temporary video folder. INCLUDE END SLASH.
 Dim TempDir: TempDir = "P:\Temp\"
 ' Set this to your temporary video name. NO EXTENSION.
 Dim TempFile: TempFile = "TMPGEncBatcher"
 ' Set this to trailing text in your .AVI name that's not in your .MPEG files.
 ' For example, my lagarith avifiles are named as "Shot 02.01.03 Morning.Laggy.avi" while the mpegs are called "Shot 02.01.03 Morning.mpg"
 Dim aviTrail: aviTrail = ".Laggy"
 ' Similar for the mpegfile, if you want to do something crazy like appending a date.
 ' Note that this is included in the search for already mpegged files.
 Dim mpgTrail: mpgTrail = ""
 
 
 
 
 
 
 ' Begin
 Main
 
 Sub Main
 ' set globals
 Set currentFolder = fso.GetFolder(".")
 fileDone = 0: fileSkip = 0
 
 ' Begin output
 WScript.Echo "**************************"
 WScript.Echo "* RED MpegBatcher script *"
 WScript.Echo "**************************"
 WScript.Echo ""
 WScript.Echo "Sending unprocessed .AVI files to TMPGEnc from this directory: "
 WScript.Echo currentFolder.Path
 WScript.Echo "While looking for:"
 WScript.Echo "'[Filenames]" & aviTrail & ".avi' files without"
 WScript.Echo "'[Filenames]" & mpgTrail & ".mpg' counterparts."
 WScript.Echo ""
 If Not promptYesNo("Continue? (y/n): ") Then Exit Sub
 WScript.Echo ""
 
 ' Start the process if there's a batch project
 If fso.FileExists(TMPGEncPath & "CurrentBatch.tbe") Then
 ' Make template copy of CurrentBatch.tbe to reset finished state again and again
 WScript.Echo "Backing up CurrentBatch.tbe ..."
 Set fsoDo = fso.GetFile(TMPGEncPath & "CurrentBatch.tbe")
 fsoDo.Copy(TMPGEncPath & "CurrentBatch.tbe.bak")
 
 ' Parse folder
 parseFolder currentFolder
 
 ' Ergo Conclusio
 WScript.Echo fileDone & " files encoded; " & fileSkip & " files were already encoded."
 WScript.Echo "Press ENTER to exit."
 Else
 WScript.Echo "You did not save your project as a Batch List in TMPGEnc!"
 End If
 
 ' Pause so the promt doesn't close immediately
 Do While Not WScript.StdIn.AtEndOfLine
 Dim Input: Input = WScript.StdIn.Read(1)
 Loop
 WScript.Echo "Done."
 
 End Sub
 
 
 
 Sub parseFolder (ByVal Folder)
 ' Prepare vars
 Dim Files: Set Files = Folder.Files
 Dim File
 
 ' Loop through dir
 For Each File In Files
 Dim fileBase: fileBase = fso.getBaseName(File.Name)
 Dim fileExt: fileExt = fso.getExtensionName(File.Name)
 If UCase(fileExt) = "AVI" Then
 fileMpeg = Replace(fileBase, aviTrail, mpgTrail) & ".mpg"
 If Not fso.FileExists(currentFolder.Path & "\" & fileMpeg) Then
 WScript.Echo File.Name & " found without " & fileMpeg
 doTMPGEnc File
 Else
 fileSkip = fileSkip + 1
 End If
 End If
 Next
 End Sub
 
 Sub doTMPGEnc (ByVal File)
 ' Dim vars
 Dim tmpAvi: tmpAvi = TempDir & TempFile & ".avi"
 Dim tmpMpeg: tmpMpeg = TempDir & TempFile & ".mpg"
 
 ' Check if temp files exists, delete..
 If fso.FileExists(tmpAvi) Then
 WScript.Echo "Deleting " & tmpAvi & " ..."
 fso.DeleteFile(tmpAvi)
 End If
 If fso.FileExists(tmpMpeg) Then
 WScript.Echo "Deleting " & tmpMpeg & " ..."
 fso.DeleteFile(tmpMpeg)
 End If
 
 ' Copy target file to temp file
 Set fsoDo = fso.GetFile(File)
 WScript.Echo "Copying " & File.Name & " to " & TempDir & "..."
 fsoDo.copy(TempDir)
 WScript.Echo "Renaming " & File.Name & " to " & TempFile & ".avi" & "..."
 Set fsoDo = fso.GetFile(TempDir & File.Name)
 ''fsoDo.Rename(TempDir & TempFile & ".avi") '' Not working?
 fsoDo.Move(TempDir & TempFile & ".avi")
 
 ' Reset Batch List template
 resetBatchList
 
 ' Run TMPGEnc in batch + autoclose mode
 WScript.Echo "Starting " & TMPGEnc & "..."
 run chr(34) & TMPGEncPath & TMPGEnc & chr(34) & " /batch /close"
 fileDone = fileDone + 1
 
 ' Reset Batch List template again, (You'd understand why if you was debugging this script)
 resetBatchList
 
 ' Successful? Delete .avi
 If fso.FileExists(tmpAvi) Then
 WScript.Echo "Deleting " & tmpAvi & " ..."
 fso.DeleteFile(tmpAvi)
 End If
 
 ' and move .mpg
 WScript.Echo "Moving '" & tmpMpeg & "' to " & currentFolder.Path
 Set fsoDo = fso.GetFile(tmpMpeg)
 fsoDo.Move(currentFolder.Path & "\" & fileMpeg)
 End Sub
 
 Function resetBatchList()
 WScript.Echo "Resetting CurrentBatch.tbe ..."
 If fso.FileExists(TMPGEncPath & "CurrentBatch.tbe") Then
 fso.DeleteFile(TMPGEncPath & "CurrentBatch.tbe")
 End If
 Set fsoDo = fso.GetFile(TMPGEncPath & "CurrentBatch.tbe.bak")
 fsoDo.Copy(TMPGEncPath & "CurrentBatch.tbe")
 End Function
 
 Function promptYesNo(ByVal strMsg)
 Do
 WScript.Echo strMsg
 Dim key: key = WScript.StdIn.ReadLine()
 Select Case LCase(Trim(key))
 Case "n","no" promptYesNo = False: Exit Function
 Case "y","yes" promptYesNo = True: Exit Function
 End Select
 WScript.StdOut.WriteLine "Just enter 'y' or 'n'..."
 Loop
 End Function
 
 Sub run(ByVal executable)
 Dim shell: Set shell = CreateObject("WScript.Shell")
 shell.Run executable, 1, true
 Set shell = Nothing
 End Sub